_gemname='faraday-follow_redirects'
_gitname='faraday-follow-redirects'
pkgname="ruby-${_gemname}"
pkgver=0.3.0
pkgrel=1
pkgdesc='Faraday adapter for Net::HTTP'
arch=('any')
url="https://github.com/tisba/$_gitname"
license=('MIT')
depends=('ruby' 'ruby-faraday')
makedepends=('ruby-rspec')
checkdepends=('ruby-rspec' 'ruby-webmock')
options=('!emptydirs')
source=("${url}/archive/v${pkgver}/${_gitname}-v${pkgver}.tar.gz")
sha512sums=('357b9618f203749f806b7882b39dfd1b90a403c9a76734f4d3ae59ef2a70430254e616be66fb5a0ec74e770e2ee9df6e0f805b00f70a6f99de12ff70fa4d2bda')

prepare() {
  cd "${_gitname}-${pkgver}"

  # update gemspec/Gemfile to allow newer version of the dependencies
  sed --in-place --regexp-extended 's|~>|>=|g' "${_gemname}.gemspec"
}

build() {
  cd "${_gitname}-${pkgver}"

  local _gemdir="$(gem env gemdir)"

  gem build "${_gemname}.gemspec"

  gem install \
    --local \
    --verbose \
    --ignore-dependencies \
    --no-user-install \
    --install-dir "tmp_install/${_gemdir}" \
    --bindir "tmp_install/usr/bin" \
    "${_gemname}-${pkgver}.gem"

  # remove unrepreducible files
  rm -rf "tmp_install/${_gemdir}/cache/"
}

check() {
  cd "${_gitname}-${pkgver}"

  local _gemdir="$(gem env gemdir)"

  GEM_HOME="tmp_install/${_gemdir}" rake spec
}

package() {
  cd "${_gitname}-${pkgver}"

  cp -a tmp_install/* "${pkgdir}"

  install -Dm 0644 LICENSE.md --target-directory "${pkgdir}/usr/share/licenses/${pkgname}"
  install -Dm 0644 {CHANGELOG,README}.md --target-directory "${pkgdir}/usr/share/doc/${pkgname}"
}