_gemname=rackup
pkgname=ruby-$_gemname
pkgver=2.1.0
pkgrel=1
pkgdesc='Provides a command line interface for running a Rack-compatible application.'
url="https://github.com/rack/$_gemname"
arch=('any')
license=('MIT')
depends=('ruby' 'ruby-rack' 'ruby-webrick')
makedepends=('ruby-rdoc')
checkdepends=('ruby-rake' 'ruby-minitest' 'ruby-minitest-global_expectations' 'ruby-minitest-sprint')
options=('!emptydirs')
source=("${pkgname}-v${pkgver}.tar.gz::$url/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('e2f9c1e3b7d97051b8bd09d9f801f93963885de3aadba1d6560847d7548a474d')
sha512sums=('c470af246388243d2c48f244ccdc72aa8888539f5561fb1352c68ae3946713f14853820348b9a96f9507c316e0f619f111cd3cde077f6ee7f9dadc4bb2f2396d')

prepare() {
  cd ${_gemname}-${pkgver}
  sed -r 's|~>|>=|g' -i ${_gemname}.gemspec
}

build() {
  cd ${_gemname}-${pkgver}

  local _gemdir="$(gem env gemdir)"

  gem build ${_gemname}.gemspec

  gem install \
    --local \
    --verbose \
    --ignore-dependencies \
    --no-user-install \
    --install-dir "tmp_install/${_gemdir}" \
    --bindir "tmp_install/usr/bin" \
    "${_gemname}-${pkgver}.gem"

  rm -rf "tmp_install/${_gemdir}/cache/"
}

check() {
  cd ${_gemname}-${pkgver}

  local _gemdir="$(gem env gemdir)"

  GEM_HOME="tmp_install/${_gemdir}" rake test
}

package() {
  cd ${_gemname}-${pkgver}

  cp -a tmp_install/* "${pkgdir}"

  install -Dm 0644 license.md --target-directory "${pkgdir}/usr/share/licenses/${pkgname}"
  install -Dm 0644 {readme,security}.md --target-directory "${pkgdir}/usr/share/doc/${pkgname}"
}