# Maintainer: Dan Printzell <wild@archlinux.org>
# Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
# Contributor: dsboger <https://github.com/dsboger>
# Contributor: Carl George < arch at cgtx dot us >

pkgname=tilix
pkgver=1.9.5
pkgrel=4
pkgdesc="A tiling terminal emulator for Linux using GTK+ 3"
arch=('x86_64')
url="https://github.com/gnunn1/tilix"
license=('MPL')
depends=('libx11' 'gtkd' 'vte3' 'dconf' 'gsettings-desktop-schemas')
makedepends=('ldc' 'po4a' 'meson' 'appstream')
optdepends=('python-nautilus: for "Open Tilix Here" support in nautilus'
            'libsecret: for the password manager')
_nautilus_43_fix_pr=2115
source=(
  "$url/archive/$pkgver/$pkgname-$pkgver.tar.gz"
  "$url/pull/$_nautilus_43_fix_pr.patch"
)
sha256sums=(
  'e25335a3f7ab06779b957d08ffaf7698c966c3b5179d002f82ce41c692fc0b89'
  '5ad54f9627d0035f6025b684ffab831341d8bdcf597b3f4a8146b09014c418b5'
)

prepare() {
  patch --directory="$pkgname-$pkgver" --forward --strip=1 --input="${srcdir}/$_nautilus_43_fix_pr.patch"
  mkdir -p build
}

build() {
  cd build

  # Build with LDC
  export DC=ldc
  export LDFLAGS="$(echo -ne $LDFLAGS | sed -e 's/-flto=auto/--flto=full/')"

  arch-meson ../$pkgname-$pkgver

  ninja
}

package() {
  cd build

  DESTDIR="$pkgdir" ninja install
}