# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Abhishek Dasgupta <abhidg@gmail.com>
# Contributor: Gabor Nyekhelyi (n0gabor) <n0gabor@vipmail.hu>

pkgname=pitivi
pkgver=2021.05
pkgrel=3
pkgdesc='Editor for audio/video projects using the GStreamer framework'
arch=('x86_64')
url='http://pitivi.org/'
license=('LGPL')
depends=('gsound' 'gst-editing-services' 'gst-plugin-gtk' 'gst-plugins-bad' 'gst-plugins-good' 'gst-python'
         'gtk3' 'libnotify' 'libpeas' 'python-cairo' 'python-gobject' 'python-matplotlib' 'python-numpy')
makedepends=('appstream-glib' 'intltool' 'itstool' 'meson')
optdepends=('frei0r-plugins: additional video effects, clip transformation feature'
            'gst-libav: additional multimedia codecs'
            'gst-plugins-ugly: additional multimedia codecs')
source=("https://download.gnome.org/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz"
        "update-collections-import.diff")
sha256sums=('cf5693c46c42ab0da14a2e59bfcf4bc880604b41e9cd3aa8d2ebdc60827b75c7'
            'bfb36faff027b4fea4040a4beb29304604239ac1f9e9240ae23abfb987a8069c')

prepare() {
  cd "$pkgname-$pkgver"
  # https://gitlab.gnome.org/GNOME/pitivi/-/merge_requests/403
  patch -Nup 1 < ../update-collections-import.diff
}

build() {
  arch-meson $pkgname-$pkgver build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}