# Maintainer: Jerome Leclanche <jerome@leclan.ch>

pkgname=foliate
pkgver=2.6.3
pkgrel=2
pkgdesc="A simple and modern GTK eBook reader"
arch=("x86_64")
url="https://johnfactotum.github.io/foliate/"
license=("GPL3")
depends=("gjs" "iso-codes" "libwebkit2gtk-4.0.so")
makedepends=("meson" "ninja" "gettext")
optdepends=(
	"dictd: Offline dictionary support"
	"espeak-ng: Text-to-speech support; also voice package needed"
	"festival: Text-to-speech support; also voice package needed"
	"gspell: Spell-checking support"
	"hyphen: Auto-hyphenation support"
	"tracker"
)
source=("$pkgname-$pkgver.tar.gz"::"https://github.com/johnfactotum/foliate/archive/$pkgver.tar.gz"
        "use_webkit40.diff::https://github.com/johnfactotum/foliate/commit/8c00d67d57241bce965043fb98ba76782989eee5.diff")
sha256sums=('de685facecb1d014c6041dbad75a5609948a0b18b97c74e31e3a1722bccafbe4'
            '7c3c292325f79de8ce4cbe866e425f179894a01b5d78ddabf583cc382e8b5a35')

prepare() {
    cd "$srcdir/$pkgname-$pkgver"
    patch -Np 1 --no-backup-if-mismatch -i ../use_webkit40.diff
}

build() {
	cd "$srcdir/$pkgname-$pkgver"
	meson build --prefix=/usr
	ninja -C build
}

package() {
	cd "$srcdir/$pkgname-$pkgver"
	DESTDIR="$pkgdir" ninja -C build install
	ln -sv com.github.johnfactotum.Foliate "$pkgdir/usr/bin/foliate"
}