# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Tércio Martins <echo dGVyY2lvd2VuZGVsQGdtYWlsLmNvbQo= | base64 -d>

_any_commit=69753a589556c33176cb640dc880753ba21c0ac2
_optional_lite_commit=f88ac174b47a6af6e88f0137676c33e3329727d4
_pybind11_commit=e2b884c33bcde70b2ea562ffa52dd7ebee276d50
_rapidjson_commit=66eb6067b10fd02e419f88816a8833a64eb33551

_pkgname=OpenTimelineIO
pkgname=${_pkgname,,}
pkgver=0.13
pkgrel=2
pkgdesc='Open Source API and interchange format for editorial timeline information'
arch=(x86_64)
url="https://opentimeline.io/"
_url="https://github.com/PixarAnimationStudios/$_pkgname"
license=('custom:Modified Apache')
depends=(python-aaf2)
makedepends=(cmake python-pip)
source=("$_pkgname-$pkgver.tar.gz::$_url/archive/refs/tags/v$pkgver.tar.gz"
        "any-${_any_commit}.tar.gz::https://github.com/thelink2012/any/archive/${_any_commit}.tar.gz"
        "optional-lite-${_optional_lite_commit}.tar.gz::https://github.com/martinmoene/optional-lite/archive/${_optional_lite_commit}.tar.gz"
        "pybind11-${_pybind11_commit}.tar.gz::https://github.com/pybind/pybind11/archive/${_pybind11_commit}.tar.gz"
        "rapidjson-${_rapidjson_commit}.tar.gz::https://github.com/Tencent/rapidjson/archive/${_rapidjson_commit}.tar.gz")
sha512sums=('2e11fa46e0fbb17568c578fc9619a2e9e2fdb9beb6838878f803ceb68754023d68a9c591f5c9308b5f557460beeae51c4374b970e9e63b74fb87be47221bd6b3'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP')

prepare() {
  tar -xzf "any-${_any_commit}.tar.gz" --strip 1 \
      -C   "$_pkgname-$pkgver/src/deps/any/"
  tar -xzf "optional-lite-${_optional_lite_commit}.tar.gz" --strip 1 \
      -C   "$_pkgname-$pkgver/src/deps/optional-lite/"
  tar -xzf "pybind11-${_pybind11_commit}.tar.gz" --strip 1 \
      -C   "$_pkgname-$pkgver/src/deps/pybind11/"
  tar -xzf "rapidjson-${_rapidjson_commit}.tar.gz" --strip 1 \
      -C   "$_pkgname-$pkgver/src/deps/rapidjson/"

  # Configure the installation of C++ bindings in the "/usr" directory 
  sed -i   "/CMAKE_CXX_EXTENSIONS/a IF(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)\n\  SET(CMAKE_INSTALL_PREFIX \"/usr\" CACHE STRING \" \" FORCE)\nENDIF(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)" \
           "$_pkgname-$pkgver/src/CMakeLists.txt"
}

build() {
  cd $_pkgname-$pkgver
  python setup.py build
}

package() {
  # Install Python bindings
  cd $_pkgname-$pkgver
  python setup.py install --root=$pkgdir --skip-build --optimize=1

  # Install C++ bindings
  cd build/temp.*
  make DESTDIR=$pkgdir install

  # Install license file
  install -D -m644 ../../LICENSE.txt \
                   "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
}

# vim:set ts=2 sw=2 et: