# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Christoph Drexler <chrdr at gmx dot at>

pkgname=leptonica
pkgver=1.81.1
pkgrel=2
pkgdesc="Software that is broadly useful for image processing and image analysis applications"
arch=('x86_64')
url="http://www.leptonica.com/"
license=('custom')
depends=('giflib' 'libjpeg-turbo' 'libpng' 'libtiff' 'zlib' 'libwebp' 'openjpeg2')
source=("$pkgname-$pkgver.tar.gz::https://github.com/DanBloomberg/leptonica/archive/$pkgver.tar.gz"
        "https://github.com/DanBloomberg/leptonica/commit/2881dfb049aea0821b506e5a5ed0048eef749c04.patch")
sha256sums=('e9dd2100194843a20bbb980ad8b94610558d47f623861bc80ac967f2d2ecb879'
            '751b3443a7224614221555616725d8b1dc9668f5720e1052ad45cdb94084abf4')

prepare() {
  cd "$srcdir"/leptonica-${pkgver}
  patch -R -p1 < ../2881dfb049aea0821b506e5a5ed0048eef749c04.patch
  ./autogen.sh
}

build() {
  cd "$srcdir"/leptonica-${pkgver}
  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir"/leptonica-${pkgver}
  make DESTDIR="$pkgdir" install
  install -D leptonica-license.txt "$pkgdir"/usr/share/licenses/leptonica/leptonica-license.txt
}