# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinxu.org>
# Contributor: Wael Nasreddine <gandalf@siemens-mobiles.org>
# Contributor: Tor Krill <tor@krill.nu>
# Contributor: Will Rea <sillywilly@gmail.com>
# Contributor: Valentine Sinitsyn <e_val@inbox.ru>
# Contributor: Ryszard Knop <dragoon@dragonic.eu>

pkgname=lib32-libnm
pkgver=1.30.4
pkgrel=1
pkgdesc="NetworkManager client library (32-bit)"
url="https://wiki.gnome.org/Projects/NetworkManager"
arch=(x86_64)
license=(GPL2 LGPL2.1)
_pppver=2.4.9
makedepends=(meson git vala perl-yaml intltool audit
             dhclient dhcpcd iptables iproute2 dnsmasq openresolv
             gobject-introspection gtk-doc glib2-docs python-gobject
             lib32-nss lib32-polkit lib32-curl lib32-systemd lib32-libndp lib32-jansson lib32-libpsl
             )
checkdepends=(lib32-libx11 python-dbus)
_commit=a3e45da9f984d58e3b76d6ca064033541d819eca  # tags/1.30.4^0
source=("git+https://gitlab.freedesktop.org/NetworkManager/NetworkManager.git#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd NetworkManager
  git describe --abbrev=10 | sed 's/-dev/dev/;s/-rc/rc/;s/-/+/g'
}

prepare() {
  cd NetworkManager

  # https://bugs.archlinux.org/task/70710
  git cherry-pick -n 8acad5a20cc61081438294efc634c0e245452e35
}

build() {
  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG="i686-pc-linux-gnu-pkg-config"

  # TODO VALA?

  local meson_args=(
    # system paths
    --libdir=/usr/lib32
    -D dbus_conf_dir=/usr/share/dbus-1/system.d

    # platform
    -D dist_version="$pkgver-$pkgrel"
    -D session_tracking_consolekit=false
    -D suspend_resume=systemd
    -D modify_system=true
    -D polkit_agent=true
    -D selinux=false
    -D libaudit=no

    # features
    -D iwd=false
    -D ppp=false
    -D modem_manager=false
    -D concheck=true
    -D ovs=false
    -D teamdctl=false
    -D nm_cloud_setup=false
    -D bluez5_dun=false
    -D ebpf=false
    -D nmcli=false
    -D nmtui=false

    # configuration plugins
    -D config_plugins_default=keyfile

    # handlers for resolv.conf
    -D netconfig=no
    -D config_dns_rc_manager_default=symlink

    # miscellaneous
    -D introspection=false
    -D vapi=false
    -D docs=false
    -D tests=no
    -D more_asserts=no
    -D more_logging=false
    -D qt=false
  )

  arch-meson NetworkManager build "${meson_args[@]}"
  meson compile -C build
}

package_lib32-libnm() {
  pkgdesc="NetworkManager client library"
  depends=(glib2 nss util-linux-libs jansson systemd-libs)
  provides=(libnm.so)

  mkdir -p "$pkgdir/usr/lib32"
  mv "$srcdir/build/libnm/libnm.so"{,.0,.0.1.0} "$pkgdir/usr/lib32"
}