# Maintainer : Laurent Carlier <lordheavym@gmail.com>
# Maintainer : Daenyth <Daenyth+Arch _AT_ gmail _DOT_ com>
# Contributor : wizzomafizzo <wizzomafizzo@gmail.com>
# Contributor: tochiro@no.spam.mail.berlios.de
# Contributor: sh__

pkgname=uqm
pkgver=0.8.0
pkgrel=1
pkgdesc="The Ur-Quan Masters, a port of Star Control 2"
arch=('x86_64')
url="http://sc2.sourceforge.net/"
license=('GPL')
depends=('libmikmod' 'libvorbis' 'sdl_image' 'libgl' 'glu')
makedepends=('imagemagick' 'mesa' 'namcap')
source=(https://downloads.sourceforge.net/sourceforge/sc2/uqm-${pkgver}-src.tgz
        https://downloads.sourceforge.net/sourceforge/sc2/uqm-${pkgver}-content.uqm
        config.state
        uqm
        uqm.desktop
        uqm.png)
noextract=(uqm-${pkgver}-content.uqm)
md5sums=('63c4c300736aa3ac9b841e31b9a76389'
         '6cbc9d51fa63e07c0f4d1d061136d816'
         'ca497b754edf56aab8a5791f1d2c974a'
         '07e64632fce6323a14ab558d0214b885'
         '44c83b9b9d102b99210af0036749a318'
         '06d0a72aa18e7edce6cd3c7a3a747c44')

prepare() {
  cd $pkgname-$pkgver
  cp ../config.state .
  sed -e "/INPUT_install_prefix/ s|replaceme|$pkgdir/usr|" \
      -i config.state
  sed -i 's/uqm_CFLAGS="$uqm_CFLAGS -Isrc"/uqm_CFLAGS="$CPPFLAGS $CFLAGS $uqm_CFLAGS -Isrc"/' Makeproject
  sed -i 's/uqm_CXXFLAGS="$uqm_CXXFLAGS -Isrc"/uqm_CXXFLAGS="$CPPFLAGS $CXXFLAGS $uqm_CXXFLAGS -Isrc"\nuqm_LDFLAGS="$LDFLAGS $uqm_LDFLAGS"/' Makeproject
  ./build.sh uqm reprocess_config
}

build() {
  cd $pkgname-$pkgver
  ./build.sh uqm
}
  
package() {
  cd $pkgname-$pkgver
  ./build.sh uqm install

  install -Dm644 "$srcdir"/$pkgname-$pkgver-content.uqm \
     "$pkgdir"/usr/share/uqm/content/packages/$pkgname-$pkgver-content.uqm

  # stolen from fedora!
  install -Dm644 "$srcdir"/uqm.desktop \
     "$pkgdir"/usr/share/applications/uqm.desktop
  install -Dm644 "$srcdir"/uqm.png \
     "$pkgdir"/usr/share/pixmaps/uqm.png

  rm "$pkgdir"/usr/bin/uqm
  install -Dm755 "$srcdir"/uqm "$pkgdir"/usr/bin/uqm
}