# Maintainer: Muflone http://www.muflone.com/contacts/english/
# Maintainer: Bruno Pagani <archange@archlinux.org>
# 27.9.2021
# edited accroding to https://www.reddit.com/r/archlinux/comments/ohjj1g/spyder_easy_fix/ 

_pkg=spyder-kernels
pkgname=python-${_pkg}
pkgver=2.0.5
pkgrel=1
pkgdesc="Jupyter Kernels for the Spyder console"
arch=(any)
url="https://github.com/spyder-ide/spyder-kernels/"
license=(MIT)
makedepends=(python python-setuptools)
depends=(
    python-cloudpickle
    python-ipykernel
    python-jupyter_client
    python-pyzmq
    python-wurlitzer    
)
checkdepends=(
    cython
    python-dask
    python-distributed
    python-flaky
    python-matplotlib
    python-mock
    python-numpy
    python-pandas
    python-pillow
    python-pytest
    python-scipy
    python-xarray    
    python-flask
    python-flask-compress
    python-brotli
)
# No tests in pypi tarballs
#source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
#source=(${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
source=(${url}/archive/refs/tags/v${pkgver}.tar.gz)
sha256sums=('868d25ec867f61e8cb26623e44e218b15e707a74a406c489e1f546c77ea045b1')
#sha256sums=('dd97f3a43d6d1a2ff2d58a3b46c57d6edd88fa6c93aad3f4e48dd9054bfd5778')

build() {
  cd ${_pkg}-${pkgver}
  python setup.py build
}

check() {
  cd ${_pkg}-${pkgver}
  pytest spyder_kernels
}

package() {
  cd ${_pkg}-${pkgver}
  python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
  install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}/
}