# Maintainer: George Rawlinson <george@rawlinson.net.nz>

_pkgname=timescaledb
pkgname=timescaledb-old-upgrade
pkgver=2.2.0
_oldver=2.1.1
pkgrel=1
pkgdesc='TimescaleDB build for migrating between major versions'
arch=('x86_64')
url="https://www.timescale.com/"
license=('Apache' 'custom:Timescale')
depends=("timescaledb=${pkgver}" 'postgresql-old-upgrade')
makedepends=('gcc' 'cmake' 'postgresql' 'postgresql-libs')
source=("$pkgname-$_oldver.tar.gz::https://github.com/timescale/timescaledb/archive/${_oldver}.tar.gz")
b2sums=('d0aa5b231cbc9a75bb65eae395ffc0063a94bd3d9c47fe2b1f80bdf59c7624c83e3d4343f3d4ea402654627b8396936614f105fc7d01612f3ea03124471b44a3')

build() {
  cd "$_pkgname-$_oldver"
  ./bootstrap -DWARNINGS_AS_ERRORS=OFF -DREGRESS_CHECKS=OFF
  cd build && make timescaledb timescaledb-tsl
}

package() {
  cd "$_pkgname-$_oldver"

  # shared libraries
  install -vDm644 -t "$pkgdir/usr/lib/postgresql" \
    "build/src/$_pkgname-$_oldver.so" \
    "build/tsl/src/$_pkgname-tsl-$_oldver.so"

  # licenses
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" \
    LICENSE LICENSE-APACHE tsl/LICENSE-TIMESCALE
}

# vim: ts=2 sw=2 et: