# Contributor: damir <damir@archlinux.org>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
# Maintainer: Gaetan Bisson <bisson@archlinux.org>

_pkgname=anthy
pkgname=${_pkgname}-emacs-patch
conflicts=('anthy')
provides=('anthy')
pkgver=9100h
_filecode=37536
pkgrel=1
pkgdesc='Hiragana text to Kana Kanji mixed text Japanese input method'
arch=('x86_64')
url='https://osdn.net/projects/anthy/'
license=('LGPL' 'GPL')
source=("http://dl.sourceforge.jp/anthy/${_filecode}/${_pkgname}-${pkgver}.tar.gz"
        anthy-emacs-fix.patch)
sha512sums=('315ebd9e1af208f3ecaeaa13620213b35f004e47edb54e60c3e02c2997444cd2326cc58b725dd2d0bd6a723130884d946ea193ea3d92418082256b59ecc8d88b'
            SKIP)

prepare() {
	cd "${srcdir}/${_pkgname}-${pkgver}"
	patch -Np1 -i "${srcdir}/anthy-emacs-fix.patch"
}

build() {
	cd "${srcdir}/${_pkgname}-${pkgver}"
	./configure --prefix=/usr --sysconfdir=/etc
	make
}

package() {
	cd "${srcdir}/${_pkgname}-${pkgver}"
	make EMACS=emacs DESTDIR="${pkgdir}" install
}