# Maintainer: Giancarlo Razzolini <grazzolini@archlinux.org>
# Contributor: Nissar Chababy <funilrys at outlook dot com>
# Contributor: Thrasibule <guillaume dot horel at gmail dot com>
# Contributor: David Manouchehri <manouchehri@riseup.net>
# Contributor: Vladimir Tsanev <tsachev@gmail.com>
# Contributor: Andrew Reed <reed.996@osu.edu>
# Contributor: "Score_Under" <seejay.11@gmail.com>

pkgname=python-lz4
_pkgname=lz4
pkgver=3.1.1
pkgrel=1
pkgdesc="LZ4 bindings for Python"
arch=('x86_64')
license=('BSD')
url="https://github.com/python-lz4/python-lz4"
depends=('python')
makedepends=('python-setuptools-scm' 'python-pkgconfig')
checkdepends=('python-pytest' 'python-psutil')
source=("https://pypi.org/packages/source/${_pkgname:0:1}/$_pkgname/$_pkgname-${pkgver}.tar.gz")
sha512sums=('b6ddcabcb323b88eeff1fa9cb91d379d6435ab51b2b51e080138892fbce57d92c8175e2ae1ef72e8a2f95429aaa4be66a5e8cd9d4dbc5bcd6b44ec26b7df96db')

build() {
  cd "$srcdir"/$_pkgname-$pkgver
  python setup.py build
}

check() {
  cd "$srcdir"/$_pkgname-$pkgver
  python -m pytest
}

package() {
  cd $_pkgname-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
}