# Maintainer: Felix Yan <felixonmars@archlinux.org>
_pkgname=brotlicffi
pkgname=python-brotlicffi
pkgver=1.0.9.1
pkgrel=1
pkgdesc='Python binding to the Brotli library'
arch=('x86_64')
license=('MIT')
url='https://github.com/python-hyper/brotlicffi'
depends=('brotli' 'python-cffi')
makedepends=('python-setuptools')
checkdepends=('python-pytest-runner' 'python-hypothesis' 'brotli-testdata')
source=("$pkgname-$pkgver.tar.gz::https://github.com/python-hyper/$__pkgname/archive/v$pkgver.tar.gz")
sha512sums=('669c73ed6dd18be6b916bb8cfb240657dcc10d67df5a32b3359f05cadf75aa654c27b53e8b964251f6d6cd74870e159efddf87ef0cfb59b7777eacd3cda66852')

prepare() {
  cd $_pkgname-$pkgver
  sed -i 's|^TEST_DATA_DIR = .*|TEST_DATA_DIR = "/usr/share/brotli/testdata"|' test/conftest.py
  rm test/test_compatibility.py #not compatible with shared library
  export USE_SHARED_BROTLI=1
}

build() {
  cd $_pkgname-$pkgver
  python setup.py build
}

check() {
  cd $_pkgname-$pkgver
  python setup.py pytest
}

package() {
  cd $_pkgname-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}