pkgname=influxdb
pkgver=2.0.4
_commit_sha=4e7a59b
pkgrel=1
pkgdesc='Scalable datastore for metrics, events, and real-time analytics'
arch=('x86_64')
url='https://github.com/influxdata/influxdb'
license=('MIT')
depends=('gcc-libs')
makedepends=('go' 'git' 'protobuf' 'yarn' 'cargo' 'clang')
source=("$pkgname-$pkgver.tar.gz::https://github.com/influxdata/influxdb/archive/v${pkgver}.tar.gz"
    "influxdb.service")

build() {
  cd "$pkgname-$pkgver"
  export CGO_CPPFLAGS="${CPPFLAGS}"
  export CGO_CFLAGS="${CFLAGS}"
  export CGO_CXXFLAGS="${CXXFLAGS}"
  export CGO_LDFLAGS="${LDFLAGS}"
  export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
  export LDFLAGS="-linkmode external"

  # parallel make jobs are not supported
  make -j1 VERSION=$pkgver COMMIT=$_commit_sha INFLUXDB_SHA=$_commit_sha
}


check() {
  cd "$pkgname-$pkgver"

  go test ./...
}

package() {
  cd "$pkgname-$pkgver"

  install -Dm644 ../influxdb.service "$pkgdir/usr/lib/systemd/system/influxdb.service"

  install -d "$pkgdir/usr/bin/"
  install -Dm755 bin/linux/influx         "$pkgdir/usr/bin/"
  install -Dm755 bin/linux/influxd        "$pkgdir/usr/bin/"

  install -Dm644 LICENSE                  "$pkgdir/usr/share/licenses/influxdb/LICENSE"
}

sha256sums=('73ebee977b8f2235eea5d280d7d9fcff8e29cf1e61c5c370ae9939d92f085c6d'
            '63fab190728f71bbdd976e11e32a3cf4a03922db737e51ea6be9209f9f437a8d')