pkgname=influxdb
pkgver=2.0.3
_commit_sha=fe04d34
pkgrel=1
pkgdesc='Scalable datastore for metrics, events, and real-time analytics'
arch=('x86_64')
url='https://github.com/influxdata/influxdb'
license=('MIT')
depends=('gcc-libs')
makedepends=('go' 'git' 'bzr' 'protobuf' 'yarn' 'cargo' 'clang')
backup=('etc/influxdb/influxdb.conf')
source=("$pkgname-$pkgver.tar.gz::https://github.com/influxdata/influxdb/archive/v${pkgver}.tar.gz"
    "influxdb.service")

build() {
  cd "$pkgname-$pkgver"
  export CGO_CPPFLAGS="${CPPFLAGS}"
  export CGO_CFLAGS="${CFLAGS}"
  export CGO_CXXFLAGS="${CXXFLAGS}"
  export CGO_LDFLAGS="${LDFLAGS}"
  export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
  export LDFLAGS="-linkmode external"

  make VERSION=$pkgver COMMIT=$_commit_sha INFLUXDB_SHA=$_commit_sha
}


check() {
  cd "$pkgname-$pkgver"

  go test ./...
}

package() {
  cd "$pkgname-$pkgver"

  install -Dm644 ../influxdb.service "$pkgdir/usr/lib/systemd/system/influxdb.service"

  install -d "$pkgdir/usr/bin/"
  install -Dm755 bin/linux/influx         "$pkgdir/usr/bin/"
  install -Dm755 bin/linux/influxd        "$pkgdir/usr/bin/"

  install -Dm644 LICENSE                  "$pkgdir/usr/share/licenses/influxdb/LICENSE"
}

sha256sums=('b25229fb010dbde40475a481d12ef95c52649db206799ede0e46bb0bb4576531'
            'a22ba54f10fa98ec4e81e864c0c3181e53dedd9e23e1d112ac4ad22c4fa4d9ee')