pkgname=influxdb
pkgver=2.0.2
_commit_sha=84496e5
pkgrel=1
pkgdesc='Scalable datastore for metrics, events, and real-time analytics'
arch=('x86_64')
url='https://github.com/influxdata/influxdb'
license=('MIT')
makedepends=('go' 'git' 'bzr' 'protobuf' 'yarn')
backup=('etc/influxdb/influxdb.conf')
source=("$pkgname-$pkgver.tar.gz::https://github.com/influxdata/influxdb/archive/v${pkgver}.tar.gz"
    "influxdb.service")

build() {
  cd "$pkgname-$pkgver"
  export CGO_CPPFLAGS="${CPPFLAGS}"
  export CGO_CFLAGS="${CFLAGS}"
  export CGO_CXXFLAGS="${CXXFLAGS}"
  export CGO_LDFLAGS="${LDFLAGS}"
  export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
  export LDFLAGS="-linkmode external"

  make VERSION=$pkgver COMMIT=$_commit_sha INFLUXDB_SHA=$_commit_sha
}


check() {
  cd "$pkgname-$pkgver"

  go test ./...
}

package() {
  cd "$pkgname-$pkgver"

  install -Dm644 ../influxdb.service "$pkgdir/usr/lib/systemd/system/influxdb.service"

  install -d "$pkgdir/usr/bin/"
  install -Dm755 bin/linux/influx         "$pkgdir/usr/bin/"
  install -Dm755 bin/linux/influxd        "$pkgdir/usr/bin/"

  install -Dm644 LICENSE                  "$pkgdir/usr/share/licenses/influxdb/LICENSE"
}

sha256sums=('272c6b8463e01547a7b349147db0e4a10ffedb59d96ad598b63b9bd20a486e7b'
            '6c8d252a6d3bf89d1491dd1df8da3d1a03619dc9d9e3363b2f90688755cb4d43')