# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Patryk Kowalczyk < patryk at kowalczyk dot ws>

pkgname=spice
pkgver=0.14.3
pkgrel=1
pkgdesc="SPICE server"
arch=('x86_64')
url="https://www.spice-space.org/"
license=('LGPL2.1')
depends=('pixman' 'opus' 'libjpeg-turbo' 'gst-plugins-base-libs')
makedepends=('meson' 'spice-protocol' 'libcacard')
checkdepends=('gdk-pixbuf2' 'glib-networking')
optdepends=('gst-libav: GStreamer support for avenc_mjpeg video encoding'
            'gst-plugins-good: GStreamer support for vp8enc and vp9enc video encoding'
            'gst-plugins-ugly: GStreamer support for x264enc video encoding')
provides=('libspice-server.so')
source=("https://www.spice-space.org/download/releases/spice-server/$pkgname-$pkgver.tar.bz2"{,.sign})
sha256sums=('551d4be4a07667cf0543f3c895beb6da8a93ef5a9829f2ae47817be5e616a114'
            'SKIP')
validpgpkeys=('206D3B352F566F3B0E6572E997D9123DE37A484F') # Victor Toso <victortoso@redhat.com>

build() {
  arch-meson "$pkgname-$pkgver" build
  ninja -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}