# Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>

pkgbase=man-pages-l10n
pkgname=(man-pages-{de,fr,nl,pl,pt_BR,ro})
pkgver=4.0.0
pkgrel=1
pkgdesc="Translation of Linux man pages"
arch=('any')
url="https://salsa.debian.org/manpages-l10n-team/manpages-l10n"
license=('GPL3')
depends=('man-db')
makedepends=('po4a')
#changelog=$pkgbase.changelog
options=('!emptydirs')
source=(https://salsa.debian.org/manpages-l10n-team/manpages-l10n/-/archive/v$pkgver/manpages-l10n-v$pkgver.tar.bz2)
sha256sums=('ee147b459a5aa83c467110521a0c661441feb7fd864971b5c970a7fa8d794219')

build() {
  cd "${srcdir}"/manpages-l10n-v$pkgver

  ./configure --prefix=/usr --enable-distribution=archlinux
  make
}

check() {
  cd "${srcdir}"/manpages-l10n-v$pkgver
  make check -k
}

package_man-pages-de() {
  pkgdesc="German Linux man pages"
  cd "${srcdir}"/manpages-l10n-v$pkgver/po/de

  make DESTDIR="${pkgdir}" install
  
#FS#65878 fix
  rm "${pkgdir}"/usr/share/man/de/man1/lzcat.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/lzcmp.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/lzdiff.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/lzegrep.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/lzfgrep.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/lzgrep.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/lzless.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/lzma.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/lzmadec.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/lzmore.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/unlzma.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/unxz.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/xz.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/xzcat.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/xzcmp.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/xzdec.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/xzdiff.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/xzegrep.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/xzfgrep.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/xzgrep.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/xzless.1.gz \
     "${pkgdir}"/usr/share/man/de/man1/xzmore.1.gz
}

package_man-pages-fr() {
  pkgdesc="French Linux man pages"
  cd "${srcdir}"/manpages-l10n-v$pkgver/po/fr

  make DESTDIR="${pkgdir}/" install
}

package_man-pages-nl() {
  pkgdesc="Dutch Linux man pages"
  cd "${srcdir}"/manpages-l10n-v$pkgver/po/nl

  make DESTDIR="${pkgdir}/" install
}

package_man-pages-pl() {
  pkgdesc="Polish Linux man pages"
  cd "${srcdir}"/manpages-l10n-v$pkgver/po/pl

  make DESTDIR="${pkgdir}/" install
}

package_man-pages-pt_BR() {
  pkgdesc="Portuguese (Brazil) Linux man pages"
  cd "${srcdir}"/manpages-l10n-v$pkgver/po/pt_BR

  make DESTDIR="${pkgdir}/" install
}

package_man-pages-ro() {
  pkgdesc="Romanian Linux man pages"
  cd "${srcdir}"/manpages-l10n-v$pkgver/po/ro

  make DESTDIR="${pkgdir}/" install
}