# Maintainer: Brad Fanella <cesura@archlinux.org>
# Contributor: Martin Wimpress <code@flexion.org>
# Contributor: Chris Lea <chris.lea@gmail.com>

pkgname=mate-terminal
pkgver=1.24.0
pkgrel=3
pkgdesc="The MATE Terminal Emulator"
url="https://mate-desktop.org"
arch=('x86_64')
license=('GPL')
depends=('libsm' 'gettext' 'mate-desktop' 'vte3')
makedepends=('itstool' 'python')
groups=('mate-extra')
conflicts=('mate-terminal-gtk3')
replaces=('mate-terminal-gtk3')

# The two .patch files are here to fix URL highlighting and search functionality, both
# of which are broken in the official 1.24.0 release due to incompatibilities with
# newer versions of the vte library.
#
# Links to upstream references:
# https://github.com/mate-desktop/mate-terminal/pull/329
# https://github.com/mate-desktop/mate-terminal/pull/332
#
# The MATE team does not think this warrants a new point release as it's just two
# commits and other distros (Debian, Fedora) have applied these patches without
# bumping the version. The patches here give MATE users on Arch a mate-terminal
# with correct URL highlighting and search functionality.
#
# TODO: Remove both .patch files and their corresponding sha256sums when a new
# official version is released that includes these fixes.
source=("https://pub.mate-desktop.org/releases/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz"
        "https://github.com/mate-desktop/mate-terminal/commit/c21a7b374f420b224c24307325061b3bb55aa3bf.patch"
        "https://github.com/mate-desktop/mate-terminal/commit/9d128954c0e60b6cd8a10a55a243a070fc780fd8.patch")

sha256sums=("274d98e3646980b93366daa23ca72a91afc85a41bf1879dc7342f9b9aa1d8259"
            "380810b77996c055ed49d7120f5b446a5f8fd470ec4c8b3d858f74166e366cab"
            "ad290b4ef6bfc4fdbe3711d92592edb9fce409e17aebccbad1520111b8617b63")

prepare() {
        cd "$pkgname-$pkgver"
        patch -p1 -i "$srcdir/c21a7b374f420b224c24307325061b3bb55aa3bf.patch"
        patch -p1 -i "$srcdir/9d128954c0e60b6cd8a10a55a243a070fc780fd8.patch"
}

build() {
        cd "${pkgname}-${pkgver}"
        ./configure \
            --prefix=/usr
        make
}

package() {
        cd "${pkgname}-${pkgver}"
        make DESTDIR="${pkgdir}" install
}