# Maintainer: Antonio Rojas <arojas@archlinux.org>

pkgname=avogadrolibs
pkgver=1.93.0
pkgrel=2
pkgdesc="Libraries that provide 3D rendering, visualization, analysis and data processing useful in computational chemistry, molecular modeling, bioinformatics, materials science, and related areas"
arch=(x86_64)
url="https://www.openchemistry.org/"
license=(custom)
depends=(molequeue glew spglib libmsym libarchive python)
makedepends=(cmake eigen boost)
source=($pkgname-$pkgver.tar.gz::"https://github.com/OpenChemistry/avogadrolibs/archive/$pkgver.tar.gz")
sha256sums=('01fea1f3b21c69091c60739616f86123db92f445e4c9ca53f1dec09624aceab4')

prepare() {
  mkdir -p build
  export CXXFLAGS="$CXXFLAGS -faligned-new"
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DUSE_MMTF=OFF \
    -DBUILD_GPL_PLUGINS=ON \
    -DOpenGL_GL_PREFERENCE=GLVND \
    -DUSE_PYTHON=ON \
    -DPYTHON_EXECUTABLE=/usr/bin/python
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
  install -Dm644 "$srcdir"/$pkgname-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
}