# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer: Christian Rebischke <chris.rebischke@archlinux.org>
# Contributor: Carl George < arch at cgtx dot us >

pkgbase=python-unittest2
_pyname=unittest2
pkgname=('python-unittest2' 'python2-unittest2')
pkgver=1.1.0
pkgrel=6
pkgdesc="New features in unittest for Python"
url="http://www.voidspace.org.uk/python/articles/unittest2.shtml"
arch=('any')
license=('BSD')
makedepends=('python' 'python2' 'python2-distribute' 'python-distribute')
source=("https://files.pythonhosted.org/packages/7f/c4/2b0e2d185d9d60772c10350d9853646832609d2f299a8300ab730f199db4/unittest2-1.1.0.tar.gz"
        'LICENSE')
sha512sums=('3fba15728905f437767416ab4fd3573d3fb2319486ef84c52a9fa930ea84aa1f2ae29d6f58993e3509083625790e17b1ef8d9ac5de0e166c254897a3e7a202fa'
            '85242ed21eb191fa0bab16f3e390957f1c8b7bc3b79aefbea2d925feaa8248f33d6e22afaa7d1c07c5fcb5e800910aa2a1cb52d892c104337bbdb57a380373a2')

prepare() {
  #sed -i "s/'argparse', //" ${_pkgname}-${pkgver}/setup.py
  cp -a "${_pyname}-${pkgver}"{,-py2}

}

build() {
    msg2 "Building python..."
  (cd "${_pyname}-${pkgver}"
    python setup.py build
  )
  msg2 "Building python2..."
  (cd "${_pyname}-${pkgver}-py2"
    python2 setup.py build
  )
}

package_python-unittest2() {
  depends=('python')
  cd "${_pyname}-${pkgver}"
  python setup.py install --skip-build -O1 --root="${pkgdir}"
  install -Dm 644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  install -Dm 644 README.txt "${pkgdir}/usr/share/doc/${pkgname}/README"
}

package_python2-unittest2() {
  depends=('python2')
  cd "${_pyname}-${pkgver}-py2"
  python2 setup.py install --skip-build -O1 --root="${pkgdir}"
  install -Dm 644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  install -Dm 644 README.txt "${pkgdir}/usr/share/doc/${pkgname}/README"
}