# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=qt5-wayland
_qtver=5.13.0
pkgver=${_qtver/-/}
pkgrel=2
arch=('x86_64')
url='https://www.qt.io'
license=('GPL3' 'LGPL3' 'FDL' 'custom')
pkgdesc='Provides APIs for Wayland'
depends=('qt5-declarative' 'libxcomposite' 'wayland') # namcap note: wayland is needed for nvidia-libgl users
groups=('qt' 'qt5')
_pkgfqn="${pkgname/5-/}-everywhere-src-${_qtver}"
source=("https://download.qt.io/official_releases/qt/${pkgver%.*}/${_qtver}/submodules/${_pkgfqn}.tar.xz"
        kdebug-407651.patch::"https://code.qt.io/cgit/qt/qtwayland.git/patch/?id=21a5038f"
        qtbug-76397.patch::"https://github.com/qt/qtwayland/commit/ec9057081f1094fbfeb11449bc533997731e4079.patch"
        qtbug-76657.patch::"https://github.com/qt/qtwayland/commit/a4e6f88f50d1a1dd56df77ce8b07b98aceb20ddc.patch")
sha256sums=('b67a6d8119628bca3301bd03992880db07d61d405534067c9cd2a598695a7cf3'
            'f21ff86a4ffb4ba7648cba8d6434d7b0a8caa8abf650ba382d3cfa63c934e01b'
            '6a24bf5a964d177d8d07dd02e3b46ecc0038549d2620527994ca952d697c7d23'
            '552307bc346d61182ac2917b38430d47e551d97e5b1bc0f7df7869f0d5eeae12')

prepare() {
  mkdir -p build

  cd $_pkgfqn
  patch -p1 -i ../kdebug-407651.patch # Prevent windows from getting larger after closing and reopening https://bugs.kde.org/show_bug.cgi?id=407651
  patch -p1 -i ../qtbug-76397.patch # Client: Fix stuttering when the GUI thread is busy - precondition for QTBUG-76657
  patch -p1 -i ../qtbug-76657.patch # fix for "QtWayland: hidden window won't show again"
}

build() {
  cd build

  qmake ../${_pkgfqn}
  make
}

package() {
  cd build

  make INSTALL_ROOT="$pkgdir" install

  # Drop QMAKE_PRL_BUILD_DIR because reference the build dir
  find "$pkgdir/usr/lib" -type f -name '*.prl' \
    -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;

  install -d "$pkgdir"/usr/share/licenses
  ln -s /usr/share/licenses/qt5-base "$pkgdir"/usr/share/licenses/${pkgname}
}