# Maintainer: Matt Parnell/ilikenwf <parwok@gmail.com>

pkgname=mcomix-gtk3-git
_pkgname=mcomix3
pkgver=r1738.e3a2e52
pkgrel=1
pkgdesc="A comic book reader. Ported to GTK3 & Python3, works well with hidpi."
arch=('any')
url="https://github.com/multiSnow/mcomix3"
license=('GPL')
depends=('python-pillow' 'python-gobject')
optdepends=('libunrar: for rar compressed comics' \
            'p7zip: for 7z compressed comics' \
            'unrar: for rar compressed comics' \
            'unzip: for zip compressed comics' \
            'mupdf: for PDF comics')
provides=("mcomix")
conflicts=("mcomix" "mcomix-git")
source=(git+https://github.com/multiSnow/mcomix3)
sha256sums=('SKIP')

pkgver() {
  cd "${_pkgname}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
  cd "${srcdir}/${_pkgname}"

  # setup.py doesn't work – setting up manually

  # their installer
  python installer.py --srcdir=mcomix --target="${pkgdir}"/usr/lib/python3.7

  # but leave out the additional directory, so the module is in the correct directory
  mv "${pkgdir}"/usr/lib/python3.7/mcomix "${pkgdir}"/usr/lib/python3.7/site-packages
  mkdir "${pkgdir}"/usr/bin
  mv "${pkgdir}"/usr/lib/python3.7/site-packages/mcomixstarter.py "${pkgdir}"/usr/bin/mcomix
  mv "${pkgdir}"/usr/lib/python3.7/site-packages/comicthumb.py "${pkgdir}"/usr/bin/comicthumb

  # other files
  install -Dm644 "${srcdir}/${_pkgname}"/man/* -t "${pkgdir}"/usr/share/man/man1/
  install -Dm644 "${srcdir}/${_pkgname}"/mime/mcomix.appdata.xml -t "${pkgdir}"/usr/share/metainfo/
  install -Dm644 "${srcdir}/${_pkgname}"/mime/mcomix.desktop -t "${pkgdir}"/usr/share/applications/
  install -Dm644 "${srcdir}/${_pkgname}"/mime/mcomix.xml -t "${pkgdir}"/usr/share/mime/
  install -Dm644 "${srcdir}/${_pkgname}"/mime/comicthumb.thumbnailer -t "${pkgdir}"/usr/share/thumbnailers/

  for size in 16 22 24 32 48
  do
    install -Dm644 "${srcdir}/${_pkgname}"/mime/icons/${size}x${size}/* -t "${pkgdir}"/usr/share/icons/hicolor/${size}x${size}/mimetypes/
    mkdir "${pkgdir}"/usr/share/icons/hicolor/${size}x${size}/apps/
    ln -s /usr/lib/python3.7/site-packages/mcomix/images/${size}x${size}/mcomix.png \
      "${pkgdir}"/usr/share/icons/hicolor/${size}x${size}/apps/
  done
  rm "${pkgdir}"/usr/lib/python3.7/site-packages/mcomix/images/mcomix-large.png
}