# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
# Contributor: Preecha Patumchareonpol <yumyai at gmail.com> 

pkgname=podofo
pkgver=0.9.6
pkgrel=2
pkgdesc="A C++ library to work with the PDF file format"
arch=('x86_64')
url="http://podofo.sourceforge.net"
license=('GPL')
depends=('lua' 'openssl' 'fontconfig' 'libtiff' 'libidn' 'libjpeg-turbo')
makedepends=('cmake' 'subversion')
source=("svn+https://svn.code.sf.net/p/podofo/code/podofo#revision=1931")
md5sums=('SKIP')

_backports=(1933 #CVE-2017-7381 AVG-216
            1936 #CVE-2017-7382 AVG-216
            1937 #CVE-2017-7383 AVG-216
            1938 #CVE-2018-11256
            1941 #CVE-2017-8054 CVE-2018-11254
            1942 #cmake3-12 compatibility
            1943 #pkgconfig fixes generated .pc
            1945 #openssl1-1-0g
            1948 #CVE-2018-12982
            1949 #CVE-2018-5783
            1950 #CVE-2018-19532
            1952 #CVE-2018-11255
            1953 #CVE-2018-14320
            1954 #CVE-2018-20751 AVG-867
            1963 #heapoverflow
            1969 #CVE-2019-9687
            1971 #CVE-2019-9199
            1986 #nullptr
            1991 #nullptr
            1994 #infinite recursion
            1995 #nullptr
            #1996 #nullptr #only needed if 1990 is backported
            #1997 #nullptr #only needed if 1990 is backported
            )

prepare() {
  cd $pkgname/trunk
  local _r
  for _r in "${_backports[@]}"; do
    svn merge -c $_r ^/podofo/trunk
  done
}

build() {
  cd $pkgname/trunk

  mkdir -p build
  cd build
  cmake -DCMAKE_INSTALL_PREFIX=/usr .. \
        -DFREETYPE_INCLUDE_DIR=/usr/include/freetype2 \
        -DPODOFO_BUILD_SHARED=1 \
        -DPODOFO_HAVE_JPEG_LIB=1 \
        -DPODOFO_HAVE_PNG_LIB=1 \
        -DPODOFO_HAVE_TIFF_LIB=1
  make
}

package() {
  cd $pkgname/trunk/build
  make DESTDIR="$pkgdir" install
}