# Maintainer: Kyle Keen <keenerd@gmail.com>
# Contributor: Lex Black <autumn-wind at web dot de>
# Contributor: Vladimir Kirillov <proger@wilab.org.ua>

pkgname=libpgm
pkgver=5.2.122
pkgrel=4
pkgdesc="OpenPGM: implementation of the Pragmatic General Multicast (PGM, RFC3208)"
arch=('x86_64')
url='https://www.freshports.org/net/openpgm/'
license=('LGPL2.1')
depends=('glibc')
makedepends=('python2')
options=(!strip)
#source=("http://openpgm.googlecode.com/files/$pkgname-$pkgver.tar.gz")
source=("https://storage.googleapis.com/google-code-archive-downloads/v2/code.google.com/openpgm/libpgm-$pkgver.tar.gz"
	"0001-pkg-config-do-not-add-I-to-non-existing-directory.patch")
sha256sums=('6b895f550b95284dcde7189b01e04a9a1c1f94579af31b1eebd32c2207a1ba2c'
	'92bd27f9caa63168a26184e82503f2acf630c3ff74c23828c57abca6cc9a99fc')


prepare() {
  cd "$srcdir/$pkgname-$pkgver/"
  git apply ../0001-pkg-config-do-not-add-I-to-non-existing-directory.patch 
  cd "$srcdir/$pkgname-$pkgver/openpgm/pgm"
  find . -type f -exec sed -i 's/python/python2/g' {} \+
}

build() {
  cd "$srcdir/$pkgname-$pkgver/openpgm/pgm"
  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver/openpgm/pgm"
  make prefix="$pkgdir/usr" install
}