# Maintainer: David Runge <dave@sleepmap.de>
_name=xvfbwrapper
pkgbase=python-xvfbwrapper
pkgname=(python-xvfbwrapper python2-xvfbwrapper)
pkgver=0.2.9
pkgrel=2
pkgdesc="Manage headless displays with Xvfb (X virtual framebuffer)"
arch=('any')
url="https://github.com/cgoldberg/xvfbwrapper"
license=('MIT')
depends=('xorg-server-xvfb')
makedepends=('python-setuptools' 'python2-setuptools')
checkdepends=('python-pytest' 'python-mock' 'python2-pytest' 'python2-mock')
source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
sha512sums=('800f3489b2e1bbc884d7651e344ed73783d6c00856f3ab7ccfa6b9058dd6d3bb98d38f11172ba89dff5773d6c5b773bc000786c1f6c6aae5a27179b37017851e')

# ${pkgname//[^2]/} is "2" if a 2 is contained in pkgname, and "" otherwise.
# In short, it's the Python version for this package.

prepare() {
  cp -av "${srcdir}/${_name}-${pkgver}" "${srcdir}/python-xvfbwrapper-${pkgver}"
  mv -v "${srcdir}/${_name}-${pkgver}" "${srcdir}/python2-xvfbwrapper-${pkgver}"

  find "${srcdir}/python2-xvfbwrapper-${pkgver}" \
    -type f -name '*.py' \
    -exec sed -i -e 's|^#!/usr/bin/env python$|#!/usr/bin/env python2|' {} +
}

build() {
  for v in 2 ''; do
    cd "${srcdir}/python${v}-${_name}-${pkgver}"
    python${v} setup.py build
  done
}

check() {
  for v in 2 ''; do
    cd "${srcdir}/python${v}-${_name}-${pkgver}"
    PYTHONPATH="${srcdir}/python${v}-${_name}-${pkgver}/build:${PYTHONPATH}" py.test${v}
  done
}

_package() {
  depends+=(python${1})
  cd "${srcdir}/python${1}-${_name}-${pkgver}"
  python${1} setup.py install --skip-build \
    --optimize=1 \
    --root="${pkgdir}/"
  install -vDm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}/"
  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}

package_python-xvfbwrapper() {
  _package ''
}

package_python2-xvfbwrapper() {
  _package 2
}
# vim:set ts=2 sw=2 et: