# $Id$
# Maintainer:
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Douglas Soares de Andrade <douglas@archlinux.org>

pkgname=mercurial
pkgver=4.4.2
pkgrel=1
pkgdesc="A scalable distributed SCM tool"
arch=('x86_64')
url="https://www.mercurial-scm.org/"
license=('GPL')
depends=('python2')
optdepends=('tk: for the hgk GUI')
backup=('etc/mercurial/hgrc')
validpgpkeys=('2BCCE14F5C6725AA2EA8AEB7B9C9DC824AA5BDD5'
              '3A8155163D0E20A530FCB78647A67FFAA346AACE')  
source=("https://www.mercurial-scm.org/release/${pkgname}-${pkgver}.tar.gz"{,.asc}
        'mercurial.profile')
sha256sums=('dc2f72caccd6b760226753d48c2f4e8889fe176a6b23ef50775caac55ce28b85'
            'SKIP'
            '87427151713e689cd87dc50d50c048e0e58285815e4eb61962b50583532cbde5')

prepare() {
  cd ${pkgname}-${pkgver}
  sed -i -e 's#env python#env python2#' mercurial/lsprof.py
  cp contrib/zsh_completion contrib/zsh_completion_chg
  sed -i -e 's/hg/chg/g' contrib/zsh_completion_chg
  cp contrib/bash_completion contrib/bash_completion_chg
  sed -i -e 's/hg/chg/g' contrib/zsh_completion_chg
}

build() {
  cd ${pkgname}-${pkgver}/contrib/chg
  make
}

package() {
  cd ${pkgname}-${pkgver}
  python2 setup.py install --root="${pkgdir}/" --optimize=1

  install -d ${pkgdir}/usr/share/man/{man1,man5}
  install -m644 doc/hg.1 "${pkgdir}/usr/share/man/man1"
  install -m644 doc/{hgrc.5,hgignore.5} "${pkgdir}/usr/share/man/man5"
  install -m755 contrib/hgk "${pkgdir}/usr/bin"
  install -m644 -D contrib/zsh_completion "${pkgdir}/usr/share/zsh/site-functions/_hg"
  install -m644 -D contrib/zsh_completion_chg "${pkgdir}/usr/share/zsh/site-functions/_chg"
  install -m644 -D contrib/bash_completion "${pkgdir}/usr/share/bash-completion/completions/hg"
  install -m644 -D contrib/bash_completion_chg "${pkgdir}/usr/share/bash-completion/completions/chg"
  install -d "${pkgdir}/usr/share/emacs/site-lisp"
  install -m644 contrib/{mq.el,mercurial.el} "${pkgdir}/usr/share/emacs/site-lisp"

  vimpath="${pkgdir}/usr/share/vim/vimfiles"
  install -Dm644 contrib/vim/HGAnnotate.vim "${vimpath}/syntax/HGAnnotate.vim"

  # set some variables
  install -m755 -d ${pkgdir}/etc/profile.d
  install -m755 ${srcdir}/mercurial.profile "${pkgdir}/etc/profile.d/mercurial.sh"

  # install configuration file
  install -m755 -d ${pkgdir}/etc/mercurial
  # install -m644 contrib/sample.hgrc "${pkgdir}/etc/mercurial/hgrc"

  # FS#38825 - Add certs config to package
  echo -e "\n[web]\ncacerts = /etc/ssl/certs/ca-certificates.crt\n" >> "${pkgdir}/etc/mercurial/hgrc"

  cd contrib/chg
  make DESTDIR="${pkgdir}" PREFIX=/usr install
}