# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>

pkgname=libuv
pkgver=1.39.0
pkgrel=1
pkgdesc="Multi-platform support library with a focus on asynchronous I/O"
arch=('x86_64')
url="https://github.com/libuv/libuv"
license=('custom')
depends=('glibc' 'libnsl')
makedepends=('python-sphinx')
source=("https://dist.libuv.org/dist/v$pkgver/libuv-v$pkgver.tar.gz"{,.sign})
sha512sums=('1aee93078efc5afe488c261c90d1d9f7b4b74f609eb2b404c0e7d47a36dc46ab71b0bf93d4eca8ccb1afb83acad1156460409f38c6e8bc1ce8285b35e6f390fe'
            'SKIP')
# PGP key IDs are available from https://github.com/libuv/libuv/blob/v1.x/MAINTAINERS.md
validpgpkeys=(
  '57353E0DBDAAA7E839B66A1AFF47D5E4AD8B4FDC' # pubkey-cjihrig-kb
)

build() {
	cd $pkgname-v$pkgver
	./autogen.sh
	./configure --prefix=/usr
	make
	make man -C docs
}

check() {
	cd $pkgname-v$pkgver
	make check
}

package() {
	cd $pkgname-v$pkgver

	make DESTDIR="$pkgdir" install

	install -Dm644 LICENSE \
		"$pkgdir"/usr/share/licenses/$pkgname/LICENSE
	install -Dm644 AUTHORS \
		"$pkgdir"/usr/share/doc/$pkgname/AUTHORS
	install -Dm644 README.md \
		"$pkgdir"/usr/share/doc/$pkgname/README.md
	install -Dm644 ChangeLog \
		"$pkgdir"/usr/share/doc/$pkgname/ChangeLog
	install -Dm644 docs/build/man/libuv.1 \
		"$pkgdir"/usr/share/man/man1/libuv.1
}