# $Id$
# Maintainer: Vesa Kaihlavirta <vegai@iki.fi>
# Contributor: Angelo Theodorou <encelo@users.sourceforge.net>

pkgname=warzone2100
pkgver=3.2.3
pkgrel=3
pkgdesc="3D realtime strategy game on a future Earth"
url="http://wz2100.net/"
arch=('x86_64')
license=('GPL')
depends=('sdl2' 'glew' 'fribidi' 'openal' 'libvorbis' 'libtheora' 'physfs' 'ttf-dejavu' 'qt5-script' 'xorg-xrandr')
makedepends=('gawk' 'flex' 'zip' 'unzip' 'asciidoc' 'mesa')
source=("http://downloads.sourceforge.net/project/warzone2100/releases/${pkgver}/${pkgname}-${pkgver}.tar.xz"
    https://github.com/Warzone2100/warzone2100/commit/3ec60e3.patch
)
sha256sums=(
    'fcab9e860203e7dacda6ee60384da490a9d44aeafc07aa31ff25f9c548be7582'
    '908fabd22ab66e8d838270b34aa4df2decdac91c55de8b5f6c9d15c3cd56565d'
)

prepare() {
  cd $pkgname-$pkgver
  patch -p1 -i ../3ec60e3.patch
}

build() {
  cd ${pkgname}-${pkgver}

  ./configure --prefix=/usr --with-distributor="ArchLinux"

  make
}

package() {
  cd ${pkgname}-${pkgver}

  make DESTDIR=${pkgdir} install
}