# $Id$
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Michel Brabants <michel.linux@tiscali.be>

pkgname=seahorse
pkgver=3.20.0+101+g1711310f
pkgrel=1
pkgdesc="GNOME application for managing PGP keys."
arch=(i686 x86_64)
license=(GPL)
url="http://projects.gnome.org/seahorse/"
depends=(gtk3 gcr libsecret libsoup desktop-file-utils dconf gpgme gnome-keyring)
makedepends=(libldap intltool yelp-tools gobject-introspection openssh vala gnome-common git)
optdepends=('openssh: SSH support')
provides=(x11-ssh-askpass)
groups=(gnome-extra)
_commit=1711310f5132a9af68c637d680664108debdd506  # master
source=("git+https://git.gnome.org/browse/seahorse#commit=$_commit"
  'Add-dummy-label-property-setters-to-conform-Seahor.patch')
sha256sums=('SKIP'
            '227dc13f390d896a079a1d95973dbae4295824052473dd19d0f0118434fc06ca')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  # fix https://bugs.archlinux.org/task/54675 (No entries for GnuPG/OpenSSH keys)
  patch -Np1 -i "${srcdir}/Add-dummy-label-property-setters-to-conform-Seahor.patch"
  sed -i -e 's/GNUPG_ACCEPTED="2.0.12 2.1.4"/GNUPG_ACCEPTED="2.2.0"/' ./configure.ac
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd "$pkgname"
    ./configure \
        --prefix=/usr \
        --sysconfdir=/etc \
        --localstatedir=/var \
        --enable-ldap \
        --disable-schemas-compile \
        --enable-hkp

  make
}

package() {
  cd "$pkgname"
  make DESTDIR="$pkgdir" install
}