# $Id$
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Michel Brabants <michel.linux@tiscali.be>

pkgname=seahorse
pkgver=3.20.0+101+g1711310f
pkgrel=1
pkgdesc="GNOME application for managing PGP keys."
arch=(i686 x86_64)
license=(GPL)
url="http://projects.gnome.org/seahorse/"
depends=(gtk3 gcr libsecret libsoup desktop-file-utils dconf gpgme gnome-keyring)
makedepends=(libldap intltool yelp-tools gobject-introspection openssh vala gnome-common git)
optdepends=('openssh: SSH support')
provides=(x11-ssh-askpass)
groups=(gnome-extra)
_commit=1711310f5132a9af68c637d680664108debdd506  # master
source=("git+https://git.gnome.org/browse/seahorse#commit=$_commit"
        'Add-dummy-label-property-setters-to-conform-Seahor.patch')
sha256sums=('SKIP'
            '9f3b2414b42439524048cf816c4772e882b371146d4fa7d3fa35f77b6f6f2124')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  patch -Np1 -i "${srcdir}/Add-dummy-label-property-setters-to-conform-Seahor.patch"
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd "$pkgname"
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
      --enable-ldap --enable-hkp --disable-schemas-compile
  make
}

package() {
  cd "$pkgname"
  make DESTDIR="$pkgdir" install
}