# $Id$
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Michel Brabants <michel.linux@tiscali.be>

pkgname=seahorse
pkgver=3.20.0
pkgrel=3
pkgdesc="GNOME application for managing PGP keys."
arch=(i686 x86_64)
license=(GPL)
url="http://projects.gnome.org/seahorse/"
depends=(gtk3 gcr libsecret libsoup desktop-file-utils dconf gpgme gnome-keyring)
makedepends=(libldap intltool yelp-tools gobject-introspection openssh gnome-common git)
optdepends=('openssh: SSH support')
provides=(x11-ssh-askpass)
groups=(gnome-extra)
source=("http://ftp.gnome.org/pub/GNOME/sources/${pkgname}/${pkgver:0:4}/${pkgname}-${pkgver}.tar.xz"
  'fix.key.considered.patch'
  'fix.key.description.patch')
sha256sums=('e2b07461ed54a8333e5628e9b8e517ec2b731068377bf376570aad998274c6df'
            '83723cb451e2acec4363af18bc43f91f8177c79aeb1d84fd40f02d70df9b51aa'
            'a65e7200c119f0af9f26658b7f269652bac973c1ad6e8e46e1ae52f646f9461f')

prepare() {
  cd "${pkgname}-${pkgver}"
  # cherry-picked upstream post-3.20.0 patches
	patch -Np1 -i "${srcdir}/fix.key.considered.patch"
  patch -Np1 -i "${srcdir}/fix.key.description.patch"
}

build() {
  cd "${pkgname}-${pkgver}"
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
    --enable-ldap --enable-hkp --disable-schemas-compile --disable-valac
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="$pkgdir" install
}