# $Id$
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Imanol Celaya <ornitorrincos@archlinux-es.org>
# Contributor: Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Contributor: Dan Vratil <progdan@progdansoft.com>
# Contributor: thotypous <matiasΘarchlinux-br·org>
# Contributor: delor <bartekpiech gmail com>

pkgname=qtcreator
pkgver=4.3.0
pkgrel=2
pkgdesc='Lightweight, cross-platform integrated development environment'
arch=('i686' 'x86_64')
url='http://qt-project.org'
license=('LGPL')
depends=('qt5-tools' 'qt5-quickcontrols' 'qt5-quickcontrols2' 'qt5-webengine' 'clang' 'qbs')
makedepends=('git' 'mesa' 'llvm')
options=('docs')
optdepends=('qt5-doc: integrated Qt documentation'
            'qt5-examples: welcome page examples'
            'qt5-translations: for other languages'
            'gdb: debugger'
            'cmake: cmake project support'
            'x11-ssh-askpass: ssh support'
            'git: git support'
            'mercurial: mercurial support'
            'bzr: bazaar support'
            'valgrind: analyze support')
source=("http://download.qt.io/official_releases/qtcreator/${pkgver%.*}/${pkgver}/qt-creator-opensource-src-${pkgver}.tar.xz"
        "use-sys-qbs.patch")
sha512sums=('462d2494d54c5b528ed187a43365a296c08ad2b104ada451a91d381f070472433ef91856f80a4d94091919296c95820e5d546800fc26a43a9709a6329fba02bb'
            '8ef1066d805ab492a64f90c15703466a033832ce1d28264accec726e2451939066996768da2093feae6fb929516f7d0cc0983957f184b3154892c61a3a7fa5ca')

prepare() {
  [[ -d build ]] && rm -r build
  mkdir build

  # Use system Qbs (see qtcreator.pro @ 32)
  # Luc: Do not delete the whole src/shared/qbs directory because it is required for building Qbs Project Manager plugin
  cd qt-creator-opensource-src-${pkgver}/
  rm src/shared/qbs/qbs.pro
  patch -i ../use-sys-qbs.patch
}

build() {
  cd build

  QTC_PREFIX=/usr LLVM_INSTALL_DIR=/usr QBS_INSTALL_DIR=/usr qmake QMAKE_CFLAGS_ISYSTEM=-I \
      CONFIG+=journald -r ../qt-creator-opensource-src-${pkgver}/qtcreator.pro

  make
  make docs
}

package() {
  cd build

  make INSTALL_ROOT="${pkgdir}/usr/" install
  make INSTALL_ROOT="${pkgdir}/usr/" install_docs

  install -Dm644 ${srcdir}/qt-creator-opensource-src-${pkgver}/LICENSE.GPL3-EXCEPT ${pkgdir}/usr/share/licenses/qtcreator/LICENSE.GPL3-EXCEPT
}