# $Id$
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor: Chris <seitz.christoph@gmail.com>
# Contributor: m0ikz <ndelatorre@moikz.com.ar>
# Contributor: atweiden <archbaum@gmail.com>
# Contributor: Jonathon Fernyhough <jonathon_at_manjaro_dot_org>

pkgname=(ansible python-ansible)
pkgver=2.3.0.0
pkgrel=5
pkgdesc='Radically simple IT automation platform'
arch=('any')
url='http://www.ansible.com'
license=('GPL3')
depends=('python2' 'python2-yaml' 'python2-paramiko' 'python2-jinja' 'python2-crypto')
optdepends=('sshpass: for ssh connections with password'
            'python2-passlib: crypt values for vars_prompt'
            'python2-netaddr: for the ipaddr filter'
            'python2-systemd: log to journal'
            'python2-pywinrm: connect to Windows machines'
            'python2-ovirt-engine-sdk: ovirt support'
            'python2-jmespath: json_query support')
makedepends=('asciidoc' 'fakeroot' 'python' 'python2-setuptools'
             'python-setuptools') 
backup=('etc/ansible/ansible.cfg')
source=("https://releases.ansible.com/ansible/ansible-${pkgver}.tar.gz")
sha512sums=('88ac28befefd7a70c36d8c33bc1aba1b0a5ffdea4bddd0b9e6c5488c70057662812208c221e47721c5a194fc30282a33490f196a719d9eb6d9b1e7dcfd1ff941')

prepare() {
  # Fix for https://bugs.archlinux.org/task/53724
  # Patch from https://github.com/ansible/ansible/pull/23710
  patch -p0 <<EOF
--- ${pkgname}-${pkgver}/lib/ansible/plugins/connection/__init__.py
+++ ${pkgname}-${pkgver}/lib/ansible/plugins/connection/__init__.py
@@ -258,6 +258,8 @@ def check_password_prompt(self, b_output):
             if not b_lines:
                 return False
             return b_lines[-1].strip().endswith(b_prompt) or b_lines[0].strip().endswith(b_prompt)
+        else:
+            return self._play_context.prompt(b_output)
 
     def check_incorrect_password(self, b_output):
         b_incorrect_password = to_bytes(gettext.dgettext(self._play_context.become_method, C.BECOME_ERROR_STRINGS[self._play_context.become_method]))
EOF

  cp -r ${pkgname}-${pkgver} "${srcdir}"/${pkgname}-${pkgver}-python
}

build() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  python2 setup.py build

  cd "${srcdir}"/${pkgname}-${pkgver}-python
  python setup.py build
}

package_ansible() {
  provides=('python2-ansible')

  cd ${pkgname}-${pkgver}
  python2 setup.py install -O1 --root="${pkgdir}"
  install -Dm644 COPYING "${pkgdir}"/usr/share/doc/ansible/COPYING

  install -d "${pkgdir}"/usr/share/ansible/doc
  cp -dpr --no-preserve=ownership ./examples "${pkgdir}"/usr/share/ansible/doc/
  install -Dm644 examples/ansible.cfg "${pkgdir}"/etc/ansible/ansible.cfg

  install -d "${pkgdir}"/usr/share/man/man1
  cp -dpr --no-preserve=ownership docs/man/man1/*.1 "${pkgdir}"/usr/share/man/man1
}

package_python-ansible() {
  pkgdesc='python bindings for ansible'
  depends=('python-paramiko' 'python-jinja' 'python-yaml' 'python-crypto')

  cd "${srcdir}"/ansible-${pkgver}-python
  python setup.py install --root=${pkgdir} --optimize=1
  rm "${pkgdir}"/usr/bin/ansible*
}