pkgname=hdf5
_patch=patch1
pkgver=1.10.0_${_patch}
pkgrel=2
pkgdesc="General purpose library and file format for storing scientific data"
arch=('i686' 'x86_64')
url="https://support.hdfgroup.org/HDF5/"
license=('custom')
depends=('zlib' 'openmpi')
makedepends=('time' 'gcc-fortran')
replaces=('hdf5-cpp-fortran' 'hdf5-openmpi' 'hdf5-fortran-openmpi')
conflicts=('hdf5')
provides=('hdf5' 'hdf5-cpp-fortran' 'hdf5-openmpi' 'hdf5-fortran-openmpi')
source=("https://support.hdfgroup.org/ftp/HDF5/releases/${pkgname}-${pkgver:0:4}/${pkgname}-${pkgver/_/-}/src/${pkgname}-${pkgver/_/-}.tar.bz2"
        'mpi.patch')
md5sums=('f6d980febe2c35c11670a9b34fa3b487'
         'dfa8dd50b8a7ebb3ad7249c627156cf9')

build() {
  cd ${pkgname}-${pkgver/_/-}
  ./configure \
    CXX="mpicxx" \
    CC="mpicc" \
    FC="mpif90" \
    F9X="mpif90" \
    RUNPARALLEL="mpirun" \
    OMPI_MCA_disable_memory_allocator=1 \
    --prefix=/usr \
    --disable-static \
    --enable-hl \
    --enable-build-mode=production \
    --with-pic \
    --docdir=/usr/share/doc/hdf5/ \
    --disable-sharedlib-rpath \
    --enable-cxx \
    --enable-fortran \
    --enable-parallel \
    --enable-unsupported \
    --with-zlib
  make
}

package() {
  cd ${pkgname}-${pkgver/_/-}

  make -j1 DESTDIR="${pkgdir}" install

  install -dm755 "${pkgdir}"/usr/share/${pkgname}
  mv "${pkgdir}"/usr/share/{hdf5_examples,${pkgname}/examples}

  install -Dm644 COPYING "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}