# Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Christopher Arndt <aur -at- chrisarndt -dot- de>
# Contributor: Ray Rashif <schiv@archlinux.org>
# Contributor: Mateusz Herych <heniekk@gmail.com>

pkgname=stk
pkgver=4.6.0
pkgrel=1
pkgdesc='The Synthesis ToolKit in C++'
arch=('x86_64')
url='http://ccrma.stanford.edu/software/stk/'
license=('MIT')
depends=('alsa-lib' 'jack')
makedepends=('pkg-config')
optdepends=('tk: run provided demos/samples')
source=("https://ccrma.stanford.edu/software/stk/release/${pkgname}-${pkgver}.tar.gz"
        runtime.patch)
md5sums=('4008470eaa5f0befd81bb09066507f64'
         '36551c348340307c765fde85d4336e73')


prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # fix demo rawwaves path
  sed -i 's:\.\./\.\.:/usr/lib/stk:' projects/demo/demo.cpp

  # fix executable scripts
  patch -Np1 -i ../runtime.patch
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # add missing linker flag
  export LIBS="$LIBS -lpthread"

  # run actual build
  autoreconf
  ./configure \
    --prefix=/usr \
    --enable-shared \
    --with-alsa \
    --with-jack \
    RAWWAVE_PATH=/usr/lib/stk/${pkgname}
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}" install

  # install rawwave files
  install -Dm644 rawwaves/*.raw -t "${pkgdir}/usr/include/${pkgname}/rawwaves"
  # install license
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}