# $Id$
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: damir <damir@archlinux.org>

pkgname=x11vnc
epoch=1
pkgver=0.9.13
pkgrel=9
pkgdesc='VNC server for real X displays'
url='http://www.karlrunge.com/x11vnc/'
arch=('i686' 'x86_64')
license=('GPL2')
optdepends=('tk: GUI support'
            'net-tools: -auth guess'
            'xf86-video-dummy: Xdummy script')
depends=('openssl' 'libjpeg' 'libxtst' 'libxinerama' 'libxdamage' 'libxrandr' 'avahi')
source=("http://downloads.sourceforge.net/project/libvncserver/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz"
        'service'
        'fix-buffer-overflows.patch')
sha1sums=('f011d81488ac94dc8dce2d88739c23bd85a976fa'
          '53e1ed7f84518a699a29607a03bee2321f9f9624'
          'd30e4036bd8e26da8a7c4da29081c07eb7a9b17d')

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"
        patch -p1 -i "${srcdir}/fix-buffer-overflows.patch"
	./configure --prefix=/usr --mandir=/usr/share/man
	make
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	make DESTDIR="${pkgdir}" install
	install x11vnc/misc/{rx11vnc,Xdummy} "${pkgdir}"/usr/bin
	install -Dm644 ../service "${pkgdir}/usr/lib/systemd/system/x11vnc.service"
	rm -fr "${pkgdir}"/usr/include/rfb # provided by libvncserver
}