# $Id$
# Maintainer: Kyle Keen <keenerd@gmail.com>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Kessia 'even' Pinheiro <kessiapinheiro at gmail.com>
# Contributor: Sorin Ionescu <sorin.ionescu@gmail.com>

pkgname=ufw
pkgver=0.35
pkgrel=4
pkgdesc="Uncomplicated and easy to use CLI tool for managing a netfilter firewall"
arch=('any')
url="https://launchpad.net/ufw"
license=('GPL3')
depends=('iptables' 'python')
install=ufw.install
backup=('etc/ufw/before.rules'
        'etc/ufw/before6.rules'
        'etc/ufw/after.rules'
        'etc/ufw/after6.rules'
        'etc/ufw/ufw.conf'
        'etc/ufw/user.rules'
        'etc/ufw/sysctl.conf'
        'etc/default/ufw'
        'etc/ufw/user.rules'
        'etc/ufw/user6.rules')
source=("http://launchpad.net/$pkgname/$pkgver/$pkgver/+download/$pkgname-$pkgver.tar.gz"
        'fix_paths.patch'
        'service')
sha256sums=('662f865bc83bf8aa1a40a6fe578bc2ce796ff60a1be2c1103def7db1b91f8509'
            'c5431077712f755ce806246112ab1cfab7b063389c7bf2a85c8b48eee78ae467'
            'fdface6f4690e4748fbbd5661c02e1967a8750fdb23581d35516174017a3fe39')

prepare() {
  cd "$pkgname-$pkgver"

  patch -Np1 < "$srcdir/fix_paths.patch"
}

package() {
  cd "$pkgname-$pkgver"

  python3 setup.py install --root="$pkgdir"

  install -Dm644 "$srcdir/service" "$pkgdir/usr/lib/systemd/system/ufw.service"
  chmod 644 \
    "$pkgdir/etc/ufw/"*.{init,rules} \
    "$pkgdir/usr/share/ufw/iptables/"*.rules
}