pkgname=vtk
pkgver=8.1.1
_majorver=8.1
pkgrel=1
pkgdesc='Visualization Toolkit'
arch=('x86_64')
url='https://www.vtk.org/'
license=('BSD')
depends=('gcc-libs' 'qt4')
optdepends=('python: python bindings' 'gnuplot: plotting tools' 'graphviz: drawing tools' 'glew' 'gdal' 'ffmpeg' 'jsoncpp' 'netcdf'
            'unixodbc' 'python-autobahn' 'python-constantly' 'python-incremental' 'python-matplotlib' 'python-mpi4py' 'python-twisted')
makedepends=('boost' 'cmake' 'eigen' 'make' 'gnuplot' 'wget' 'python-autobahn' 'python-constantly' 'python-incremental' 'python-matplotlib'
             'python-mpi4py' 'python-twisted' 'gdal' 'glew' 'ffmpeg' 'lesstif' 'qt5-webkit' 'qt5-x11extras' 'jsoncpp' 'netcdf' 'unixodbc')
provides=('vtk')
conflicts=('vtk')
source=("https://www.vtk.org/files/release/${_majorver}/VTK-${pkgver}.tar.gz"
        "https://gitlab.kitware.com/dgobbi/vtk/commit/706f1b397df09a27ab8981ab9464547028d0c322.diff")
#source=("https://github.com/Kitware/VTK/archive/master.zip")
sha256sums=('71a09b4340f0a9c58559fe946dc745ab68a866cf20636a41d97b6046cb736324'
            '38b29107b1f30d731a6320daf190cbcc20a302fc1bd8a84f5b05d41efd4d485a')

prepare() {
	rm -rf build
	mkdir -p build

	cd VTK-${pkgver}
	patch -i ${srcdir}/706f1b397df09a27ab8981ab9464547028d0c322.diff -p1
}

build() {
	cd build

	# flags to enable using system libs (not covered by VTK_USE_SYSTEM_LIBRARIES)
	local cmake_system_flags=""
	for lib in TWISTED ZOPE SIX AUTOBAHN MPI4PY GLEW TXAIO HYPERLINK CONSTANTLY INCREMENTAL; do
		cmake_system_flags+="-DVTK_USE_SYSTEM_${lib}=1 "
	done

	cmake "../VTK-${pkgver}/" -DBUILD_DOCUMENTATION=0 -DBUILD_SHARED_LIBS=1 -DBUILD_TESTING=0 -DCMAKE_BUILD_TYPE=Release \
		-DCMAKE_INSTALL_LIBDIR=lib -DCMAKE_INSTALL_PREFIX=/usr -DVTK_BUILD_ALL_MODULES=1 -DVTK_PYTHON_VERSION=3 \
		-DVTK_QT_VERSION=5 -DVTK_USE_CXX11_FEATURES=1 -DVTK_USE_FFMPEG_ENCODER=1 -DVTK_USE_SYSTEM_LIBRARIES=1 \
		-DVTK_USE_SYSTEM_DIY2=0 -DVTK_USE_SYSTEM_GL2PS=0 -DVTK_USE_SYSTEM_LIBHARU=0 -DVTK_USE_SYSTEM_NETCDFCPP=0 \
		-DVTK_USE_SYSTEM_XDMF2=0 -DVTK_USE_SYSTEM_XDMF3=0 -DVTK_USE_SYSTEM_ZFP=0 -DVTK_USE_TK=0 -DVTK_WRAP_PYTHON=1 \
		-DVTK_USE_SYSTEM_PEGTL=0 -DOpenGL_GL_PREFERENCE=GLVND \
		-DXDMF_STATIC_AND_SHARED=0 $cmake_system_flags
	make
}

package() {
	cd build

	make DESTDIR="${pkgdir}" install
	install -D -m644 ${srcdir}/VTK-${pkgver}/Copyright.txt $pkgdir/usr/share/licenses/$pkgname/LICENSE
}