# $Id$
# Maintainer: Timothy Redaelli <timothy.redaelli@gmail.com>
# Contributor: Francois Boulogne <fboulogne at april dot org>

pkgbase=python-qrcode
pkgname=('python-qrcode' 'python2-qrcode')
pkgver=5.2.2
pkgrel=2
pkgdesc="Python library to generate QR codes"
arch=('any')
url="https://github.com/lincolnloop/python-qrcode"
license=('custom')
makedepends=('python-pillow' 'python-six' 'python-setuptools'
             'python2-pillow' 'python2-six' 'python2-setuptools')
source=("http://pypi.python.org/packages/source/q/qrcode/qrcode-${pkgver}.tar.gz"{,.asc})
sha256sums=('d96628a1c1807340509746a58191073468c1c6d1f3de5c26ed1fcdceadc3de19'
            'SKIP')
validpgpkeys=('012F5E34E68956C6C24A4D2FD6F44049700D3AF0')

package_python-qrcode() {
  depends=('python-pillow' 'python-six' 'python-setuptools')
  conflicts=("${pkgname}-bin")

  cd "qrcode-$pkgver"
  python setup.py clean --all
  python setup.py install --root="${pkgdir}" --optimize=1

  install -D -m644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}

package_python2-qrcode() {
  depends=('python2-pillow' 'python2-six')

  cd "qrcode-$pkgver"
  python2 setup.py clean --all
  python2 setup.py install --root="${pkgdir}" --optimize=1

  # remove executable from python2 package
  rm -rf "$pkgdir/usr/"{bin,share}

  install -D -m644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}

# vim:ts=2:sw=2:et: