# $Id$
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor : shining <shiningxc.at.gmail.com>
# Contributor : cyberdune <cyberdune@gmail.com>

pkgname=octave
pkgver=4.0.3
pkgrel=2
pkgdesc="A high-level language, primarily intended for numerical computations."
arch=('i686' 'x86_64')
url="http://www.octave.org"
license=('GPL')
depends=('fftw' 'curl' 'graphicsmagick' 'glpk' 'hdf5' 'qhull' 'fltk' 'arpack' 'glu' 'ghostscript'
 	   'suitesparse' 'gl2ps' 'qscintilla' 'libsndfile')
makedepends=('gcc-fortran' 'texlive-core' 'suitesparse' 'texinfo' 'gnuplot' 'qscintilla')
optdepends=('texinfo: for help-support in octave'
            'gnuplot: alternative plotting'
	    'java-environment-common: java support')
source=(ftp://ftp.gnu.org/gnu/octave/octave-$pkgver.tar.xz{,.sig} octave-gcc6.patch)
options=('!emptydirs')
validpgpkeys=('DBD9C84E39FE1AAE99F04446B05F05B75D36644B')  # John W. Eaton
sha1sums=('c798346a8271e0141d9dbe5610584dabb8311277'
          'SKIP'
          '646a285266faf054ae72b1897e575f08da779d6e')

prepare() {
  cd $pkgname-$pkgver
  # Fix build with GCC 6 (Fedora)
  patch -p1 -i ../octave-gcc6.patch
  find -name \*.cc -o -name \*.h -o -name \*.yy | xargs sed -i -e 's/#include <c\(math\|stdlib\)>/#include <\1.h>/'
  find -name \*.h -o -name \*.cc | xargs sed -i -e 's/<config.h>/"config.h"/' -e 's/<base-list.h>/"base-list.h"/'
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  autoreconf -vfi

  if  pacman -Qs jre > /dev/null; then
    [[ $CARCH == "x86_64" ]] && local _arch=amd64
    [[ $CARCH == "i686" ]] && local _arch=i386
    local EXTRABUILDOPTS="--with-java-homedir=/usr/lib/jvm/`archlinux-java get` 
                          --with-java-includedir=/usr/lib/jvm/`archlinux-java get`/include 
                          --with-java-libdir={/usr/lib/jvm/`archlinux-java get`/lib/${_arch}/server,/usr/lib/jvm/`archlinux-java get`/jre/lib/${_arch}/server}"
  fi

  ./configure --prefix=/usr --libexecdir=/usr/lib \
  --enable-shared --disable-static \
  --with-quantum-depth=16 \
  --with-umfpack="-lumfpack -lsuitesparseconfig"  \
  ${EXTRABUILDOPTS} \
  MOC=moc-qt4 UIC=uic-qt4
# https://mailman.cae.wisc.edu/pipermail/help-octave/2012-September/053991.html 

  LANG=C make
}

package(){
  cd "${srcdir}/${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}" install

  # add octave library path to ld.so.conf.d
  install -d "${pkgdir}/etc/ld.so.conf.d"
  echo "/usr/lib/${pkgname}/${pkgver}" > "${pkgdir}/etc/ld.so.conf.d/${pkgname}.conf"
}