# $Id$
# Maintainer: Daniel Isenmann <daniel@archlinux.org>
# Contributor: Brice Carpentier <brice@dlfp.org>

pkgname=mono
pkgver=4.2.2.10
_pkgver=4.2.2
pkgrel=1
pkgdesc="Free implementation of the .NET platform including runtime and compiler"
arch=(i686 x86_64)
license=('GPL' 'LGPL2.1' 'MPL' 'custom:MITX11')
url="http://www.mono-project.com/"
depends=('zlib' 'libgdiplus>=3.8' 'sh' 'python' 'ca-certificates')
options=('!makeflags')
provides=('monodoc')
conflicts=('monodoc')
source=("http://download.mono-project.com/sources/mono/${pkgname}-${pkgver}.tar.bz2"
        'mono.binfmt.d'
        '0001-Bump-nunit-from-mono-2.0-to-mono-4.5.patch')
md5sums=('16644eab7d890e568d34a18e93e7a878'
         'b9ef8a65fea497acf176cca16c1e2402'
         '4aff7240fea3338912e655c9e1fd567d')
install="${pkgname}.install"

prepare() {
  cd ${pkgname}-${_pkgver}
  patch -Np1 -i ${srcdir}/0001-Bump-nunit-from-mono-2.0-to-mono-4.5.patch
}

build() {
  cd "${srcdir}"/${pkgname}-${_pkgver}

  # build mono
  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --bindir=/usr/bin \
    --sbindir=/usr/bin \
    --disable-system-aot \
    --with-mcs-docs=no 
  make

  # build jay
  cd "${srcdir}"/${pkgname}-${_pkgver}/mcs/jay
  make
}

package() {
  cd "${srcdir}"/${pkgname}-${_pkgver}
  make DESTDIR="${pkgdir}" install

  # install jay
  pushd "${srcdir}"/${pkgname}-${_pkgver}/mcs/jay
  make DESTDIR="${pkgdir}" prefix=/usr INSTALL=../../install-sh install
  popd

  # install binfmt conf file and pathes
  install -D -m644 "${srcdir}"/mono.binfmt.d "${pkgdir}"/usr/lib/binfmt.d/mono.conf

  #install license
  mkdir -p "${pkgdir}"/usr/share/licenses/${pkgname}
  install -m644 mcs/MIT.X11 "${pkgdir}"/usr/share/licenses/${pkgname}/

  #fix .pc file to be able to request mono on what it depends, fixes #go-oo build
  sed -i -e "s:#Requires:Requires:" "${pkgdir}"/usr/lib/pkgconfig/mono.pc
}