# $Id$
# Maintainer: Daniel Isenmann <daniel@archlinux.org>
# Contributor: Brice Carpentier <brice@dlfp.org>

pkgname=mono
pkgver=4.3.2.467
_pkgver=4.3.2
pkgrel=1
pkgdesc="Free implementation of the .NET platform including runtime and compiler"
arch=(i686 x86_64)
url="http://www.mono-project.com/"
license=('GPL' 'LGPL2.1' 'MPL' 'custom:MITX11')
depends=('zlib' 'libgdiplus>=3.8' 'sh' 'python' 'ca-certificates')
provides=('monodoc')
conflicts=('monodoc')
install="${pkgname}.install"
source=("http://download.mono-project.com/sources/mono/${pkgname}-${pkgver}.tar.bz2"
        'mono.binfmt.d')
sha256sums=('2949e06b7301a4d9315f622bff318b77f0dc5cdd7a0f9bc086239e5fdb0c87c5'
            '9a657fc153ef4ce23bf5fc369a26bf4a124e9304bde3744d04c583c54ca47425')

build() {
  cd ${pkgname}-${_pkgver}
  ./configure \
      --prefix=/usr \
      --sysconfdir=/etc \
      --bindir=/usr/bin \
      --sbindir=/usr/bin \
      --with-mcs-docs=no
  make

  # build jay
  cd "${srcdir}"/${pkgname}-${_pkgver}/mcs/jay
  make
}

package() {
  cd ${pkgname}-${_pkgver}
  make DESTDIR="${pkgdir}" install

  # install jay
  pushd "${srcdir}"/${pkgname}-${_pkgver}/mcs/jay
  make DESTDIR="${pkgdir}" prefix=/usr INSTALL=../../install-sh install
  popd

  # install binfmt conf file and pathes
  install -D -m644 "${srcdir}"/mono.binfmt.d "${pkgdir}"/usr/lib/binfmt.d/mono.conf

  #install license
  mkdir -p "${pkgdir}"/usr/share/licenses/${pkgname}
  install -m644 mcs/MIT.X11 "${pkgdir}"/usr/share/licenses/${pkgname}/
}