# $Id$
# Maintainer: Tom Gundersen <teg@jklm.no>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=libbluedevil
pkgver=2.0
pkgrel=1
epoch=1
pkgdesc='A Qt4 wrapper for bluez used in the new KDE bluetooth stack'
arch=('i686' 'x86_64')
url="https://projects.kde.org/projects/playground/libs/libbluedevil"
license=('GPL')
depends=('qt4' 'bluez')
makedepends=('cmake')
source=("http://download.kde.org/stable/${pkgname}/${pkgver}/src/${pkgname}-${pkgver}.tar.xz"
               "${pkgname}-remove-default-power-on.patch::https://projects.kde.org/projects/playground/libs/libbluedevil/repository/revisions/c76d6e50ba6466403457371ab8416b0600af4a77/diff/bluedevil/bluedeviladapter.cpp?format=diff")
md5sums=('ab31d7d9c5dbfc8b5ca4615e7fb03100' 'SKIP')

prepare() {
  mkdir build
  patch -Rp1 -i ${srcdir}/${pkgname}-remove-default-power-on.patch
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DQT_QMAKE_EXECUTABLE=/usr/bin/qmake-qt4
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}