# $Id: PKGBUILD 90079 2013-05-06 19:39:08Z foutrelis $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
# Contributor: Preecha Patumchareonpol <yumyai at gmail.com> 

pkgname=podofo
pkgver=0.9.3
pkgrel=1
pkgdesc="A C++ library to work with the PDF file format"
arch=('i686' 'x86_64')
url="http://podofo.sourceforge.net"
license=('GPL')
depends=('openssl' 'libidn' 'lua' 'fontconfig' 'libpng' 'libtiff')
# cmake's lua detection choses the LUA51 library if both lua and lua51 are installed. lua51 does not contain some symbols needed by podofo
conflicts=('lua51')
makedepends=('cmake')
source=("http://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.gz")
md5sums=('268ca111826757ca7e3f5c4be3547e7a')

build() {
  cd ${pkgname}-${pkgver}

  mkdir build
  cd build
  cmake -DCMAKE_INSTALL_PREFIX=/usr .. \
        -DPODOFO_BUILD_SHARED=1 \
        -DPODOFO_HAVE_JPEG_LIB=1 \
        -DPODOFO_HAVE_PNG_LIB=1 \
        -DPODOFO_HAVE_TIFF_LIB=1
  make
}

package() {
  cd ${pkgname}-${pkgver}/build
  make DESTDIR=$pkgdir install
}