# $Id$
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Arjan Timmerman <arjan@archlinux.org>
# Contributor: Wael Nasreddine <gandalf@siemens-mobiles.org>
# Contributor: Tor Krill <tor@krill.nu>
# Contributor: Will Rea <sillywilly@gmail.com>

pkgbase=network-manager-applet
pkgname=(network-manager-applet libnm-gtk)
pkgver=0.9.8.10
pkgrel=2
pkgdesc="GNOME frontends to NetWorkmanager"
arch=(i686 x86_64)
license=(GPL)
url="http://www.gnome.org/projects/NetworkManager/"
depends=("networkmanager>=${pkgver%.*}" gtk3 libsecret)
makedepends=(intltool gobject-introspection modemmanager libsecret iso-codes)
options=('!emptydirs')
install=network-manager-applet.install
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/0.9/$pkgname-$pkgver.tar.xz)
sha256sums=('46fee9a1e667d1826e6a94bb6bd2e6bdbde535fc995e534542f5f7e8b8dae0cb')

build() {
  cd network-manager-applet-${pkgver}
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var \
      --libexecdir=/usr/lib/networkmanager \
      --disable-static \
      --disable-maintainer-mode \
      --disable-migration \
      --with-modem-manager-1

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package_network-manager-applet() {
  depends+=(iso-codes gnome-icon-theme mobile-broadband-provider-info libnm-gtk)
  options=(!emptydirs)

  cd network-manager-applet-${pkgver}
  make DESTDIR="${pkgdir}" install
  make DESTDIR="${pkgdir}" -C src/libnm-gtk uninstall
}

package_libnm-gtk() {
  pkgdesc="network manager GTK library"

  cd network-manager-applet-${pkgver}
  make DESTDIR="${pkgdir}" -C src/libnm-gtk install
}