# $Id$
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=libdrm
pkgver=2.4.49
pkgrel=2
pkgdesc="Userspace interface to kernel DRM services"
arch=(i686 x86_64)
license=('custom')
depends=('glibc' 'libpciaccess')
makedepends=('valgrind')
checkdepends=('cairo')
replaces=('libdrm-new' 'libdrm-nouveau')
url="http://dri.freedesktop.org/"
source=(http://dri.freedesktop.org/$pkgname/$pkgname-$pkgver.tar.bz2
        COPYING
        0001-radeon-Update-unaligned-offset-for-2D-1D-tiling-tran.patch)
sha256sums=('25d7d3fd30d8c350d3b87b3048f1c0cf0be295a40197a49acc374d4f4ae97a7d'
            '9631d4f694952e3e6ae5a05534c2e93e994e47d3413677a3a00e45c8cef6db93'
            'c004d81f2f15f01fe54dffbe1ab4a81ac2a8271c942a2ff1fbe4ac48b3599133')

build() {
  cd $pkgname-$pkgver

  patch -p1 -i ${srcdir}/0001-radeon-Update-unaligned-offset-for-2D-1D-tiling-tran.patch
  # pthread is useless in Linux
  sed -i "/pthread-stubs/d" configure.ac
  autoreconf --force --install
  
  ./configure --prefix=/usr --enable-udev
  make
}

check() {
  cd $pkgname-$pkgver
  make -k check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -m755 -d "$pkgdir/usr/share/licenses/$pkgname"
  install -m644 ../COPYING "$pkgdir/usr/share/licenses/$pkgname/"
}