# Maintainer: Florian Pritz <bluewind@xinu.at>
# Contributor: Christoph Vigano <mail@cvigano.de>

_pkgbasename=p11-kit
pkgname=lib32-$_pkgbasename
pkgver=0.18.4
pkgrel=2
pkgdesc="Library to work with PKCS#11 modules (32-bit)"
arch=(x86_64)
url="http://p11-glue.freedesktop.org"
license=('BSD')
depends=(lib32-glibc lib32-libtasn1 $_pkgbasename)
makedepends=('automake') #only needed until upstream pushes out a new release
options=(!libtool)
source=($url/releases/$_pkgbasename-$pkgver.tar.gz{,.sig}
	'with-module-config.diff::https://bugs.freedesktop.org/attachment.cgi?id=84099') #only needed until upstream pushes out a new release
md5sums=('9535c4e5b9c2ef5f5cd0755115ba098b'
	'SKIP'
	'6899438e3bfd51ea913982e55f778b78')

build() {
  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
  cd "$srcdir/$_pkgbasename-$pkgver"
  
  patch -p1 < ../with-module-config.diff #only needed until upstream pushes out a new release
  aclocal #only needed until upstream pushes out a new release
  automake #only needed until upstream pushes out a new release
  
  ./configure --prefix=/usr --libdir=/usr/lib32 --sysconfdir=/etc \
    --with-module-path=/usr/lib32/pkcs11 \
    --with-module-config=/usr/lib32/p11-kit/module-config
  make
}

package() {
  cd "$srcdir/$_pkgbasename-$pkgver"
  make DESTDIR="$pkgdir" install
  rm -rf "${pkgdir}"/etc
  rm -rf "${pkgdir}"/usr/{bin,include,share}
  install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
}

# vim:set ts=2 sw=2 et: