# $Id: PKGBUILD 94419 2013-07-23 19:26:11Z seblu $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Sébastien Luttringer

pkgname=dokuwiki
pkgver=20130510
_pkgver=${pkgver:0:4}-${pkgver:4:2}-${pkgver:6:2}
pkgrel=4
pkgdesc='Simple to use and highly versatile Open Source wiki software'
arch=('any')
url='http://www.splitbrain.org/projects/dokuwiki'
license=('GPL')
depends=('php')
backup=('etc/webapps/dokuwiki/.htaccess')
options=('!strip')
source=("http://www.splitbrain.org/_media/projects/dokuwiki/dokuwiki-${_pkgver}.tgz")
md5sums=('9cb5bb79c0445df849845b586e872677')

package() {
  cd "$pkgdir"
  install -dm0755 usr/share/webapps var/lib/dokuwiki etc/webapps
  cp -a "$srcdir"/$pkgname-${_pkgver} usr/share/webapps/dokuwiki

  # move data in var
  mv usr/share/webapps/dokuwiki/data var/lib/dokuwiki
  ln -s {/var/lib/dokuwiki,usr/share/webapps/dokuwiki}/data

  # move config in /etc
  mv usr/share/webapps/dokuwiki/conf etc/webapps/dokuwiki
  chmod g=rwx etc/webapps/dokuwiki
  ln -s /etc/webapps/dokuwiki usr/share/webapps/dokuwiki/conf

  # inform update on changes.log
  touch var/lib/dokuwiki/data/changes.log
  chmod 0644 var/lib/dokuwiki/data/changes.log

  # use default htaccess
  cp usr/share/webapps/dokuwiki/.htaccess.dist etc/webapps/dokuwiki/.htaccess
  ln -s /etc/webapps/dokuwiki/.htaccess usr/share/webapps/dokuwiki/.htaccess

  # fix rights and ownership
  chown http:http usr/share/webapps/dokuwiki/lib/plugins
  chown -R http:http var/lib/dokuwiki/data
  chown -R http:http etc/webapps/dokuwiki
}

# vim:set ts=2 sw=2 et: